원도우 환경에서 네트워크 설정을 간편하게 변경하는 방법

원도우 환경에서 네트워크 설정을 간편하게 변경하는 방법

set_ip.bat 배치 스크립트

@echo off
setlocal

:: 코드 페이지 설정 (한국어 CP949)
chcp 949 >nul

:: 기본 네트워크 인터페이스 이름
set INTERFACE_NAME=이더넷

:: 정적 IP 설정 정보
set IP_ADDR=192.168.0.10
set SUBNET_MASK=255.255.255.0
set GATEWAY=192.168.0.1
set DNS1=1.1.1.1
set DNS2=8.8.8.8

:: 메뉴 표시
echo 네트워크 설정 모드를 선택하세요:
echo 1. 정적 IP 설정
echo 2. DHCP (자동 IP) 설정
set /p CHOICE="선택 (1 또는 2): "

if "%CHOICE%"=="1" goto STATIC
if "%CHOICE%"=="2" goto DHCP
echo 잘못된 입력입니다. 1 또는 2를 입력하세요.
pause
exit

:STATIC
echo 정적 IP 설정 중...
netsh interface ipv4 set address name="%INTERFACE_NAME%" source=static addr=%IP_ADDR% mask=%SUBNET_MASK% gateway=%GATEWAY%
netsh interface ipv4 set dns name="%INTERFACE_NAME%" source=static addr=%DNS1% register=primary
netsh interface ipv4 add dns name="%INTERFACE_NAME%" addr=%DNS2% index=2
echo.
echo 정적 IP 설정 완료:
echo IP 주소: %IP_ADDR%
echo 서브넷 마스크: %SUBNET_MASK%
echo 게이트웨이: %GATEWAY%
echo DNS 서버: %DNS1%, %DNS2%
goto SHOW_CONFIG

:DHCP
echo DHCP 설정 중...
netsh interface ipv4 set address name="%INTERFACE_NAME%" source=dhcp
netsh interface ipv4 set dns name="%INTERFACE_NAME%" source=dhcp
echo.
echo DHCP 설정 완료: IP 주소가 자동으로 할당됩니다.
goto SHOW_CONFIG

:SHOW_CONFIG
echo.
echo 현재 네트워크 설정 확인 중...
ipconfig
pause
endlocal

스크립트 실행

관리자 권한으로 실행

• .bat 파일을 마우스 오른쪽 버튼으로 클릭하고 "관리자 권한으로 실행"을 선택합니다.
• 중요 : 네트워크 설정 변경을 위해 관리자 권한이 필요합니다.

네트워크 설정 모드를 선택하세요:
1. 정적 IP 설정
2. DHCP (자동 IP) 설정
선택 (1 또는 2):